KlugPush

<extensions>
    <extensionID>com.klug.push.Push</extensionID>
</extensions>

<uses-permission android:name="android.permission.POST_NOTIFICATIONS"/>
<application>
    <service android:name="com.klug.push.KlugPushMessagingService" android:exported="false">
        <intent-filter>
            <action android:name="com.google.firebase.MESSAGING_EVENT"/>
        </intent-filter>
    </service>
    <activity android:name="com.klug.push.KlugPushPermissionActivity" android:exported="false"
              android:theme="@android:style/Theme.Translucent.NoTitleBar"/>
    <provider android:name="com.klug.push.KlugPushFileProvider"
              android:authorities="air.YOUR.APP.ID.pushnotificationsfileprovider"
              android:exported="false" android:grantUriPermissions="true"/>
</application>

import com.klug.push.Push;

var push:Push = Push.getInstance();

if ( push.isSupported )   // iOS, Android, macOS
{
    // Android: notification channel with your sound file from the app root (created once).
    // iOS: only the last argument counts (show banners while the app is open).
    push.setup( "alerts", "Alerts", "alert.wav", Push.IMPORTANCE_HIGH, true );

    push.requestAuthorisation();   // system prompt, only while not decided yet
    push.register( onToken, onPushError, onNotification );
}

function onToken( token:String ):void
{
    // iOS / macOS: the APNs device token (64 hex). Android: the FCM registration token.
    if ( token != loadSavedToken() )   // your app functions
        sendTokenToServer( token );    // e.g. a POST to https://your.server/push
}

function onPushError( message:String ):void
{
    // typical causes: missing push entitlement (Apple) or google-services.json (Android)
    trace( "push registration failed: " + message );
}

import flash.events.Event;
import flash.events.StatusEvent;
import flash.desktop.NativeApplication;

// cold start: the tap launched the app
openFromPayload( push.consumeSelectedNotification() );

// warm start: the app was in the background
NativeApplication.nativeApplication.addEventListener( Event.ACTIVATE, function( e:Event ):void {
    openFromPayload( push.consumeSelectedNotification() );
});

// iOS: the app was open and the user tapped the banner.
// Consume here too, so the next ACTIVATE does not open the same screen again.
push.addEventListener( StatusEvent.STATUS, function( e:StatusEvent ):void {
    if ( e.code == Push.NOTIFICATION_SELECTED ) openFromPayload( push.consumeSelectedNotification() );
});

function openFromPayload( json:String ):void
{
    if ( json == "" ) return;                     // not opened from a notification
    var payload:Object = JSON.parse( json );       // your own keys are included
    if ( payload.hasOwnProperty( "stationId" ) )
        openLiveView( payload.stationId );           // your app function
}

function onNotification( json:String ):void
{
    // the payload as your server sent it, plus your own keys
    var payload:Object = JSON.parse( json );
    showInAppHint( payload );   // your app function; the system banner shows as well
}

// later, e.g. after the user signed in to another account
function onLogin():void
{
    if ( push.token != null )        // the last token; null until registration finished
        sendTokenToServer( push.token );
}

import flash.events.Event;
import flash.events.StatusEvent;
import flash.desktop.NativeApplication;

function updateNotificationSwitch():void
{
    var status:String = push.authorisationStatus();
    if ( status == Push.AUTHORISED )          showSwitch( "on" );    // your app function
    else if ( status == Push.DENIED )         showSwitch( "off" );
    else if ( status == Push.NOT_DETERMINED ) showSwitch( "not asked" );
}

// after a denial the system does not ask again: the way back is the settings page
function onSwitchTapped():void
{
    if ( push.authorisationStatus() == Push.DENIED ) push.openSettings();
    else push.requestAuthorisation();
}

// the answer to the prompt arrives as an event
push.addEventListener( StatusEvent.STATUS, function( e:StatusEvent ):void {
    if ( e.code == Push.AUTHORISATION ) updateNotificationSwitch();
});

// the user may have changed it in the settings: read the live status when the app comes back
NativeApplication.nativeApplication.addEventListener( Event.ACTIVATE, function( e:Event ):void {
    push.refreshStatus( function( status:int ):void { updateNotificationSwitch(); } );
});